[PATCH v2 2/3] riscv/ftrace: SAVE_ALL supports lightweight save

[Andrew Jones]

On Wed, Nov 16, 2022 at 11:13:04AM +0800, Song Shuai wrote:
> In order to make the function graph use ftrace directly, ftrace_caller
> should be adjusted to save the necessary regs against the pt_regs layout
> so it can call ftrace_graph_func reasonably.
> 
> SAVE_ALL now saves all the regs according to the pt_regs struct. Here
> introduces a lightweight option for SAVE_ALL to save only the necessary
> regs for ftrace_caller.
> 
> For convenience, the original argument setup for the tracing function in
> ftrace_[regs]_caller is killed and appended to the tail of SAVE_ALL.
> 
> Signed-off-by: Song Shuai <suagrfillet at gmail.com>
> ---
>  arch/riscv/kernel/mcount-dyn.S | 110 +++++++++++++++++++++++++++------
>  1 file changed, 92 insertions(+), 18 deletions(-)
> 
> diff --git a/arch/riscv/kernel/mcount-dyn.S b/arch/riscv/kernel/mcount-dyn.S
> index d171eca623b6..2f0a280bd7a0 100644
> --- a/arch/riscv/kernel/mcount-dyn.S
> +++ b/arch/riscv/kernel/mcount-dyn.S
> @@ -56,7 +56,51 @@
>  	.endm
>  
>  #ifdef CONFIG_DYNAMIC_FTRACE_WITH_REGS
> -	.macro SAVE_ALL
> +
> +/**
> +* SAVE_ALL - save regs against the pt_regs struct
> +*
> +* @all: tell if saving all the regs

I find it odd to have a macro name that includes 'ALL' in it
to require a parameter 'all' to be set in order to actually save
all. I suggest renaming the macro to something like SAVE_REGS.

> +*
> +* If all is set, all the regs will be saved, otherwise only ABI
> +* related regs (a0-a7,epc,ra and optional s0) will be saved.
> +*
> +* For convenience the argument setup for tracing function is appended here.
> +* Especially $sp is passed as the 4th argument of the tracing function.
> +*
> +* After the stack is established,
> +*
> +* 0(sp) stores the PC of the traced function which can be accessed
> +* by &(fregs)->regs->epc in tracing function. Note that the real
> +* function entry address should be computed with -FENTRY_RA_OFFSET.
> +*
> +* 8(sp) stores the function return address (i.e. parent IP) that
> +* can be accessed by &(fregs)->regs->ra in tracing function.
> +*
> +* The other regs are saved at the respective localtion and accessed
> +* by the respective pt_regs member.
> +*
> +* Here is the layout of stack for your reference.
> +*
> +*
> +*			=========
> +*			|  pip  |
> +* PT_SIZE_ON_STACK  ->  =========
> +*			+ ..... +
> +*			+ t3-t6 +
> +*			+ s2-s11+
> +*			+ a0-a7 + --++++-> ftrace_caller saved
> +*			+ s1    +   +
> +*			+ s0    + --+
> +*			+ t0-t2 +   +
> +*			+ tp    +   +
> +*			+ gp    +   +
> +*			+ sp    +   +
> +*			+ ra    + --+ // parent IP
> +*		sp  ->  + epc   + --+ // PC of the traced function
> +*			+++++++++
> +**/
> +	.macro SAVE_ALL, all=0
>  	addi	sp, sp, -SZREG
>  	addi	sp, sp, -PT_SIZE_ON_STACK
>  
> @@ -67,14 +111,8 @@
>  	REG_S x1,  PT_RA(sp)
>  	REG_L x1,  PT_EPC(sp)
>  
> -	REG_S x2,  PT_SP(sp)
> -	REG_S x3,  PT_GP(sp)
> -	REG_S x4,  PT_TP(sp)
> -	REG_S x5,  PT_T0(sp)
> -	REG_S x6,  PT_T1(sp)
> -	REG_S x7,  PT_T2(sp)
> -	REG_S x8,  PT_S0(sp)
> -	REG_S x9,  PT_S1(sp)
> +	/* always save the ABI regs */
> +
>  	REG_S x10, PT_A0(sp)
>  	REG_S x11, PT_A1(sp)
>  	REG_S x12, PT_A2(sp)
> @@ -83,6 +121,18 @@
>  	REG_S x15, PT_A5(sp)
>  	REG_S x16, PT_A6(sp)
>  	REG_S x17, PT_A7(sp)
> +
> +	/* save leftover regs for ftrace_regs_caller*/
> +
> +	.if \all == 1
> +	REG_S x2,  PT_SP(sp)
> +	REG_S x3,  PT_GP(sp)
> +	REG_S x4,  PT_TP(sp)
> +	REG_S x5,  PT_T0(sp)
> +	REG_S x6,  PT_T1(sp)
> +	REG_S x7,  PT_T2(sp)
> +	REG_S x8,  PT_S0(sp)
> +	REG_S x9,  PT_S1(sp)
>  	REG_S x18, PT_S2(sp)
>  	REG_S x19, PT_S3(sp)
>  	REG_S x20, PT_S4(sp)
> @@ -97,22 +147,31 @@
>  	REG_S x29, PT_T4(sp)
>  	REG_S x30, PT_T5(sp)
>  	REG_S x31, PT_T6(sp)
> +	.else
> +
> +	/* save s0 for ftrace_caller if FP_TEST defined */
> +
> +#ifdef HAVE_FUNCTION_GRAPH_FP_TEST
> +	REG_S x8,  PT_S0(sp)
> +#endif
> +	.endif
> +
> +	/* setup 4 args for tracing functions  */
> +
> +	addi	a0, ra, -FENTRY_RA_OFFSET // ip
> +	la	a1, function_trace_op
> +	REG_L	a2, 0(a1)		// op
> +	REG_L	a1, PT_SIZE_ON_STACK(sp) // parent_ip
> +	mv	a3, sp			// fregs

Please line up the comments.

>  	.endm
>  
> -	.macro RESTORE_ALL
> +	.macro RESTORE_ALL, all=0
>  	REG_L x1,  PT_RA(sp)
>  	addi	sp, sp, PT_SIZE_ON_STACK
>  	REG_S x1,  (sp)
>  	addi	sp, sp, -PT_SIZE_ON_STACK
>  	REG_L x1,  PT_EPC(sp)
> -	REG_L x2,  PT_SP(sp)
> -	REG_L x3,  PT_GP(sp)
> -	REG_L x4,  PT_TP(sp)
> -	REG_L x5,  PT_T0(sp)
> -	REG_L x6,  PT_T1(sp)
> -	REG_L x7,  PT_T2(sp)
> -	REG_L x8,  PT_S0(sp)
> -	REG_L x9,  PT_S1(sp)
> +
>  	REG_L x10, PT_A0(sp)
>  	REG_L x11, PT_A1(sp)
>  	REG_L x12, PT_A2(sp)
> @@ -121,6 +180,16 @@
>  	REG_L x15, PT_A5(sp)
>  	REG_L x16, PT_A6(sp)
>  	REG_L x17, PT_A7(sp)
> +
> +	.if \all == 1
> +	REG_L x2,  PT_SP(sp)
> +	REG_L x3,  PT_GP(sp)
> +	REG_L x4,  PT_TP(sp)
> +	REG_L x5,  PT_T0(sp)
> +	REG_L x6,  PT_T1(sp)
> +	REG_L x7,  PT_T2(sp)
> +	REG_L x8,  PT_S0(sp)
> +	REG_L x9,  PT_S1(sp)
>  	REG_L x18, PT_S2(sp)
>  	REG_L x19, PT_S3(sp)
>  	REG_L x20, PT_S4(sp)
> @@ -136,6 +205,11 @@
>  	REG_L x30, PT_T5(sp)
>  	REG_L x31, PT_T6(sp)
>  
> +	.else
> +#ifdef HAVE_FUNCTION_GRAPH_FP_TEST
> +	REG_L x8,  PT_S0(sp)
> +#endif
> +	.endif
>  	addi	sp, sp, PT_SIZE_ON_STACK
>  	addi	sp, sp, SZREG
>  	.endm
> -- 
> 2.20.1
> 
>

Thanks,
drew